Martin Krzywinski - The Perl Journal - Canada's Michael Smith Genome Sciences Centre

Volumes 1–6 (1996–2002)

Code tarballs available for issues 1–21.

I reformatted the CD-ROM contents. Some things may still be a little wonky — oh, why hello there <FONT> tag. Syntax highlighting is iffy. Please report any glaring issues.

(2001) Finance::Quotelets. The Perl Journal, vol 5(5), issue #21, Fall 2001.

# "australia" is the standard name for # looking up stocks in Australia. However # people can also access our function directly # by using the unique name of "skippy". sub methods { return (skippy => \&funds, australia=> \&funds); }

#!/usr/bin/perl -w use strict; package Finance::Quote::Quotelet::Example; use HTTP::Request::Common; # The "methods" function registers two modes, "australia" and # "my_example". Both of these call the function &myfunc. sub methods {return (australia => \&myfunc, my_example => \&myfunc)} # These are the labels my Quotelet guarantees to return. my @labels = qw/name last volume price method/; sub labels { return (australia => \@labels, my_example => \@labels); } # Here's the function that does all the hard work. sub myfunc { my $quoter = shift; # F::Q object. my @stocks = @_; my %info; # Stock info goes in this hash. my $EXAMPLE_URL = "https://www.example.oz.au/info.csv?"; # Fetch my information. In this case, our pretend # source wants the symbols appended to the end # of the URL. my $ua = $quoter->user_agent; my $response = $ua->request(GET $EXAMPLE_URL.join("+",@stocks)); # If there's an error, return an appropriate hash # with all failures. unless ($response->is_success) { foreach my $stock (@stocks) { $info{$stock,"success"} = 0; $info{$stock,"errormsg"} = "HTTP failure"; } return wantarray() ? %info : \%info; } # Parse our CSV file that's been returned, and load # into the hash. We'll split lines up on CRLF or # just LF. The first element is the stock symbol. foreach my $line (split('\015?\012',$response->content)) { my @data = $quoter->parse_csv($line); my $stock = $data[0]; # Set the success flag. If this is unset then # data may not be returned. $info{$stock,"success"} = 1; $info{$stock,"name"} = $data[1]; $info{$stock,"last"} = $data[2]; $info{$stock,"volume"} = $data[3]; # Our "price" is the same as the last # price for the stock. $info{$stock,"price"} = $info{$stock,"last"}; # Method is always our own unique name. $info{$stock,"method"} = "my_example"; } # All done. Return the array with data loaded in it. return wantarray ? %info : \%info; }

name Company or Mutual Fund Name last Last Price high Highest trade today low Lowest trade today date Last Trade Date (MM/DD/YY format) time Last Trade Time net Net Change p_change Percent Change from previous day's close volume Volume avg_vol Average Daily Vol bid Bid ask Ask close Previous Close open Today's Open day_range Day's Range year_range 52-Week Range eps Earnings per Share pe P/E Ratio div_date Dividend Pay Date div Dividend per Share div_yield Dividend Yield cap Market Capitalization ex_div Ex-Dividend Date. nav Net Asset Value yield Yield (usually 30 day avg) exchange The exchange the information was obtained from. success Did the stock successfully return information? (true/false) errormsg If success is false, this field may contain the reason why. method The module (as could be passed to fetch) which found this information.

listing 1

(2001) Finance::Quotelets. The Perl Journal, vol 5(5), issue #21, Fall 2001.

#!/usr/bin/perl -w
use strict;
# BTAust Quotelet.
# Paul Fenwick <pjf@cpan.org>, November 2000
# Insert GPL here.
package Finance::Quote::Quotelet::BTAust;
use HTML::TableExtract;
use HTTP::Request::Common;
use Data::Dumper;
# In perl 5.6 we could use 'our', but we'll try to stay 5.005 compatible.
use vars qw/$VERSION/;
$VERSION = 1.00;
# The btfunds_direct method is our unique name.  We've used
# _direct because it gets the information directly from BT's
# website, and not through a different provider.
sub methods { return (btfunds => \&btfunds, btfunds_direct => \&bt_funds); }
# The labels we guarantee to return (if they make sense):
sub labels {
    my @labels = qw/price name date entry exit yield/;
    return (btfunds => \@labels, btfunds_direct => \@labels);
}
# Which fields should undergo currency conversion:
sub currency_fields { return qw/price entry exit/; }
# These variables don't need to be calculated every time the function
# is called, so we define them in the top scope.
my $BTFUNDS_URL = "https://online.btfunds.com.au/btonline/default.asp?request= \

  MFUnitPriceHistory&FundType=RETAIL";
my %month;
@month{qw/Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec/} = 1..12;
# The actual function that does the hard work.
sub btfunds {
    my ($quoter, @symbols) = @_;
    return unless @symbols;    # No point doing work without symbols.
    # Drop our symbols into a hash for fast lookup later on.
    my %symbol_lookup;
    @symbol_lookup{@symbols} = ();
    my $ua = $quoter->user_agent;
    my %funds;    # Where we'll store the data.
    my $response = $ua->request(GET $BTFUNDS_URL);
    # Unless we have a success in the HTTP session, then
    # everything is a failure.
    unless ($response->is_success) {
        foreach my $symbol (@symbols) {
            $funds{$symbol, "errormsg"} = "HTTP failure";
            $funds{$symbol, "success"} = 0;
        }
        return wantarray() ? %funds : \%funds;
    }
    # Use HTML::TableExtract to find the information we're
    # looking for.
    my $te = HTML::TableExtract->new(headers => [
        "Product/Fund Name", "As At", "Entry Price",
        "Exit Price"]);
    $te->parse($response->content);
    # Step through each row, placing the info into our hash
    # if required.
    foreach my $row (($te->table_states)[0]->rows) {
        my ($name, $date, $entry, $exit) = @$row;
        next unless $date;    # Skips bogus rows.
        # Strip unprintables and undesirables.
        $name =~ s/[^\s\w#]/ /g;
        $date =~ s/[^\s\w]/-/g;
        # A hash on the end means this fund has a yield,
        # not a price.  We strip the hash so we can
        # compare names later on.
        $name =~ s/\s*(#?)\s*$//;
        my $yield_fund = $1;
        # Skip the row if we're not interested.
        next unless exists $symbol_lookup{$name};
        $funds{$name,"success"} = 1;
        $funds{$name,"name"} = $name;
        # Set ourselves as the module that found this info.
        $funds{$name,"method"} = "btfunds";
        # Convert the date into US format.
        $date =~ s#(\d+)-(\w+)-(\d+)#$month{$2}/$1/$3#;
        $funds{$name,"date"} = $date;
        # Note that yield funds do not have a currency,
        # only a percentage.
        if ($yield_fund) {
            $entry =~ s/%$//;    # Strip trailing percent
            $funds{$name,"yield"} = $entry;
            $funds{$name,"price"} = $entry;
        } else {
            $exit =~  s/^\$//;    # Strip leading $'s
            $entry =~ s/^\$//;
            $funds{$name,"entry"} = $entry;
            $funds{$name,"exit"} = $exit;
            $funds{$name,"currency"} = "AUD";
            $funds{$name,"price"} = $exit;
        }
    }
    # Anything not found is a failure...
    foreach my $symbol (@symbols) {
        unless ($funds{$symbol,"success"}) {
            $funds{$symbol,"success"} = 0;
            $funds{$symbol,"errormsg"} = "Symbol not found";
        }
    }
    return wantarray() ? %funds : \%funds;
}

The Perl Journal

Volumes 1–6 (1996–2002)

Finance::Quotelets

Standard Finance::Quote Labels

listing 1